| 一目均衡表の作り方を解説します。 |
| |
| 使い方はお任せします。一目均衡表の読み方・使い方はさまざまあり、厳密にこのように使う、といったものがありません。 |
| 投資家の数だけ使い方が存在するといっていいでしょう。 |
| |
| 一目均衡表は次の５つのパラメーターによって構成されます。 |
| |
| 転換線＝（○日間の高値＋○日間の安値）÷２ |
| 基準線＝（△日間の高値＋△日間の安値）÷２ |
| 先行スパン①＝（転換線＋基準線）÷２ |
| 先行スパン②＝（５２日間の高値＋５２日間の安値）÷２ |
| 遅行線＝終値（終値をその日を含めて２６日前の日付のところにもっていったもの） |
| |
| |
| チャート表示させると、先行スパンが途中から現れるチャートになります。 |
| （先行していますから） |
| |
| 次のようなレイアウトのシートを作ってみます。 |
| 要するに１０１行目からデータが始まり、Ｃ～Ｆに４本値が入るわけです。 |
| Ｇ～Ｋ列に、一目均衡表を構成する主要線が入り、Ｌ列をクロス、Ｍ列を総合判定の売り買い表示とします。 |
| |
 |
| |
|
| 転換線 |
| Ｇ１０１：＝ |
| IF(D101="","",IF(OFFSET(D101,1-G$2,0)="","",(MAX(OFFSET(D101,1-G$2,0):D101)+MIN(OFFSET(E101,1-G$2,0):E101))/2)) |
| |
| 重要な部分は、 |
| （MAX(OFFSET(D101,1-G$2,0):D101)+MIN(OFFSET(E101,1-G$2,0):E101))/2 です。 |
| （最高値（範囲指定）＋最低値（範囲指定））÷.２ ということをしています。 |
| |
| 短期と書かれているセルの下へ○日間を意味する数値を入れます。 |
| |
| |
| 一目均衡といえど難しくはありません。 |
| カッコの数が多いとか、＝””で価格データがないときに、エラーの表記をださないため、便宜的処理を入れているから |
| ややこしいだけです。解説を続けます。 |
| |
| |
| 基準線 |
| Ｈ１０１：＝ |
| IF(D101="","",IF(OFFSET(D101,1-H$2,0)="","",(MAX(OFFSET(D101,1-H$2,0):D101)+MIN(OFFSET(E101,1-H$2,0):E101))/2)) |
| |
| 重要な部分は、 |
| (MAX(OFFSET(D102,1-H$2,0):D102)+MIN(OFFSET(E102,1-H$2,0):E102))/2 です。 |
| （最高値（範囲指定）＋最低値（範囲指定））÷２ ということをしています。 |
| |
| 長期と書かれているセルの下へ△日間を意味する数値を入れます。 |
| |
| |
| 先行スパン① |
| Ｉ１０１：＝ |
| IF(OR(OFFSET(G101,1-H$2,0)="",OFFSET(H101,1-H$2,0)=""),"",(OFFSET(G101,1-H$2,0)+OFFSET(H101,1-H$2,0))/2) |
| |
| 空白だったら、どうするか？ 何を表示するかという処理が多くて、結局大切なのは、 |
| (OFFSET(G101,1-H$2,0)+OFFSET(H101,1-H$2,0))/2 です。 |
| （転換線＋基準線）÷２ をしています。 |
| |
| |
| 先行スパン② |
| Ｊ１７７：＝ |
| =(MAX(D101:D152)+MIN(E101:E152))/2 |
| |
| ５２日間の高値と安値の中間値をその日から２６日先のところに表示させなければなりません。 |
| そんなわけで、１０１行から始まるデータでは、１７７行目にこの関数式を入れます。 |
| |
| |
| 遅行線 |
| ２６日前の日付です。 |
| Ｋ１０１：＝ |
| =IF(F126="","",F126) |
| |
| 終値（終値をその日を含めて２６日前の日付のところにもっていったもの） となります。 |
| そのため、１０１行に１２６行のデータを入れることになります。 |
| |
| |
| これで主要線の算出はすみました。あとは判定をどうするかです。 |
| クロス列へ、転換線が基準線を上まわったら「ｕｐ」、それ以外なら「ｄｎ」という条件を設定します。 |
| あくまで事例のひとつです。 |
| |
| クロス |
| Ｌ１０１：＝ |
| IF(OR(G101="",H101=""),"",IF(G101>H101,"up",IF(G101=H101,L100,"dn"))) |
| |
| |
| 最後に判定列です。クロス列が「ｕｐ」なら「買い」、そうでなければ、「売り」です。 |
| |
| 判定 |
| Ｍ１０１：＝ |
| IF(OR(L100=L101,L100=""),"",IF(L101="up","買い",IF(L101="dn","売り",""))) |
| |
| 売り買いの判定まで算出することができました。 |
| ※この事例では、Ｊ２のパラメーターは使いません。 |
|
| |
| 以上で、一目均衡表の作り方を終わります。 |
| 売買判定は投資家の数だけあるので、ご自身で作ってみるといいでしょう。 |
| |
| |
| |
|
| |
|
| |
|
| TOPへ戻る |
|
